source: rtems/acinclude.m4 @ f289c09

4.104.114.84.9
Last change on this file since f289c09 was f289c09, checked in by Ralf Corsepius <ralf.corsepius@…>, on Nov 15, 2002 at 2:13:01 PM

2002-11-15 Ralf Corsepius <corsepiu@…>

  • acinclude.m4: Add CXX_FOR_*, CXXFLAGS_FOR_*. Fix stupid typo (continue/configure).
  • aclocal/prog-cc.m4: Remove obsolete comments. Acknowledge CFLAGS.
  • Property mode set to 100644
File size: 11.3 KB
Line 
1## All directories belong in one of 3 categories.
2## ${HOST_CONFIGDIRS_LIST} is directories we build using the host tools.
3## ${TARGET_CONFIGDIRS_LIST} is directories we build using the target tools.
4## ${BUILD_CONFIGDIRS_LIST} is directories we build using the build tools
5
6
7dnl RTEMS_ARG_VAR(VAR,HELP-STRING)
8dnl An internal macros to have help strings pretty
9dnl printed with configure --help, without letting autoconf spoil config subdir
10dnl environments by trying to propagate them
11dnl Stripped down version of autoconf-2.52's AC_ARG_VAR.
12
13AC_DEFUN([_RTEMS_ARG_VAR],
14[
15m4_expand_once([m4_divert_once([HELP_VAR],
16[AC_HELP_STRING([$1], [$2], [              ])])],
17      [$0($1)])dnl
18])
19
20AC_DEFUN([_RTEMS_SUBST_IFNOT],
21[AS_IF([`echo " [$]$1 " | grep " $2 " > /dev/null`],
22  [],
23  [AC_SUBST([$1],["[$]$1 $2"])])
24])
25
26AC_DEFUN([_RTEMS_COMMANDS_POST_CONFIG_SUBDIRS],
27[
28AC_CONFIG_COMMANDS_PRE([
29_RTEMS_BUILD_CONFIG_PREPARE
30_RTEMS_HOST_CONFIG_PREPARE
31_RTEMS_TARGET_CONFIG_PREPARE
32
33AS_IF([test $build = $host],
34[
35  AS_IF([test $host = $target],
36  [dnl b=h, h=t, t=b
37    BUILD_SUBDIRS="${build_configdirs}"
38    build_configdirs="${build_configdirs}"
39    HOST_SUBDIRS=""
40    host_configdirs=""
41    TARGET_SUBDIRS=""
42    target_configdirs=""],
43  [dnl b=h, h!=t, t!=b
44    BUILD_SUBDIRS="${build_configdirs}"
45    build_configdirs="${build_configdirs}"
46    HOST_SUBDIRS=""
47    host_configdirs=""
48    TARGET_SUBDIRS=`echo "${target_configdirs}" | \
49      sed -e "s%\([[^ ]][[^ ]]*\)%$target_alias/\1%g"`
50    target_configdirs="${target_configdirs}"
51  ])
52],[
53  AS_IF([test $host = $target],
54  [ dnl b!=h, h=t, b!=t
55    BUILD_SUBDIRS="${build_configdirs}"
56    build_configdirs="${build_configdirs}"
57    HOST_SUBDIRS=`echo "${host_configdirs}" | \
58      sed -e "s%\([[^ ]][[^ ]]*\)%$host_alias/\1%g"`
59    host_configdirs="${host_configdirs}"
60    TARGET_SUBDIRS=""
61    target_configdirs=""],
62  [
63    AS_IF([test $build = $target],
64    [dnl b!=h, h!=t, b=t
65      BUILD_SUBDIRS="${build_configdirs}"
66      build_configdirs="${build_configdirs}"
67      HOST_SUBDIRS=`echo "${host_configdirs}" | \
68        sed -e "s%\([[^ ]][[^ ]]*\)%$host_alias/\1%g"`
69      host_configdirs="${host_configdirs}"
70      TARGET_SUBDIRS=""
71      target_configdirs=""],
72    [dnl b!=h, h!=t, b!=t
73      BUILD_SUBDIRS="${build_configdirs}"
74      build_configdirs="${build_configdirs}"
75      HOST_SUBDIRS=`echo "${host_configdirs}" | \
76        sed -e "s%\([[^ ]][[^ ]]*\)%$host_alias/\1%g"`
77      host_configdirs="${host_configdirs}"
78      TARGET_SUBDIRS=`echo "${target_configdirs}" | \
79        sed -e "s%\([[^ ]][[^ ]]*\)%$target_alias/\1%g"`
80      target_configdirs="${target_configdirs}"
81    ])
82  ])
83])
84
85AC_SUBST(HOST_SUBDIRS)
86AC_SUBST(TARGET_SUBDIRS)
87AC_SUBST(BUILD_SUBDIRS)
88])
89
90  AC_CONFIG_COMMANDS_POST([
91    _RTEMS_OUTPUT_SUBDIRS([build],[BUILD])
92    _RTEMS_OUTPUT_SUBDIRS([host],[HOST])
93    _RTEMS_OUTPUT_SUBDIRS([target],[TARGET])
94  ])
95])
96
97dnl _RTEMS_SRCPATHS(BUILD-DIR-NAME)
98dnl ----------------------------
99dnl Inputs:
100dnl   - BUILD-DIR-NAME is `top-build -> build' and `top-src -> src'
101dnl   - `$srcdir' is `top-build -> top-src'
102dnl
103dnl Outputs:
104dnl - `ac_builddir' is `.', for symmetry only.
105dnl - `ac_top_builddir' is `build -> top_build'.
106dnl      If not empty, has a trailing slash.
107dnl - `ac_srcdir' is `build -> src'.
108dnl - `ac_top_srcdir' is `build -> top-src'.
109dnl
110dnl and `ac_buildpath' etc., the absolute paths.
111m4_define([_RTEMS_SRCPATHS],
112[
113m4_if([$2],,
114[dstdir=$1],
115[case "$2" in
116"." | "" )      # No subdir was given
117  dstdir=$1;;
118* )             # A subdir was given
119  dstdir=$2/$1;;
120esac])
121ac_builddir=.
122
123AS_IF([test $dstdir != .],
124[ # Strip off leading ./
125  ac_builddir_suffix=/`echo $dstdir | sed 's,^\.[[\\/]],,'`
126  ac_srcdir_suffix=/`echo $1 | sed 's,^\.[[\\/]],,'`
127  # A "../" for each directory in $ac_dir_suffix.
128  ac_top_builddir=`echo "$ac_builddir_suffix" | sed 's,/[[^\\/]]*,../,g'`
129],[
130  ac_dir_suffix= ac_top_builddir=
131])
132
133case $srcdir in
134  .)  # No --srcdir option.  We are building in place.
135    ac_srcdir=.
136    if test -z "$ac_top_builddir"; then
137       ac_top_srcdir=.
138    else
139       ac_top_srcdir=`echo $ac_top_builddir | sed 's,/$,,'`
140    fi ;;
141  [[\\/]]* | ?:[[\\/]]* )  # Absolute path.
142    ac_srcdir=$srcdir$ac_srcdir_suffix;
143    ac_top_srcdir=$srcdir;
144    ;;
145  *) # Relative path.
146    ac_srcdir=$ac_top_builddir$srcdir$ac_srcdir_suffix;
147    ac_top_srcdir=$ac_top_builddir$srcdir;
148    ;;
149esac
150dnl Don't blindly perform a `cd $1/$ac_foo && pwd` since $ac_foo can be
151dnl absolute.
152
153ac_buildpath=`cd $dstdir && cd $ac_builddir && pwd`
154ac_top_buildpath=`cd $dstdir && cd $ac_top_builddir && pwd`
155ac_srcpath=`cd $dstdir && cd $ac_srcdir && pwd`
156ac_top_srcpath=`cd $dstdir && cd $ac_top_srcdir && pwd`
157])# _AC_SRCPATHS
158
159dnl _RTEMS_OUTPUT_SUBDIRS([host|target|build],[HOST|TARGET|BUILD])
160AC_DEFUN([_RTEMS_OUTPUT_SUBDIRS],[
161m4_ifdef([_RTEMS_$2_CONFIGDIRS_LIST],
162[
163_RTEMS_ARG_VAR([CC_FOR_$2],
164  [c-compiler to be used for $1 subdirs (default: auto-detected)])
165_RTEMS_ARG_VAR([CFLAGS_FOR_$2],
166  [c-flags to be used for $1 subdirs (default: provided by autoconf)])
167_RTEMS_ARG_VAR([CXX_FOR_$2],
168  [c++-compiler to be used for $1 subdirs (default: auto-detected)])
169_RTEMS_ARG_VAR([CXXFLAGS_FOR_$2],
170  [c++-flags to be used for $1 subdirs (default: provided by autoconf)])
171if test "$no_recursion" != yes; then
172
173 if test -n "${$2_SUBDIRS}"; then
174   RTEMS_CONFIGURE_ARGS_QUOTE([ac_sub_configure_args],[
175     -prefix | --prefix | --prefi | --pref | --pre | --pr | --p)
176       ac_prev=prefix ;;
177     -prefix=* | --prefix=* | --prefi=* | --pref=* | --pre=* | --pr=* | --p=*)
178       ;;
179   ],[$1args])
180
181  # Always prepend --prefix to ensure using the same prefix
182  # in subdir configurations.
183  ac_sub_configure_args="'--prefix=$prefix' $ac_sub_configure_args"
184
185  case "$$1_subdir" in
186  "." ) ;;
187  * )
188    ac_sub_configure_args="$ac_sub_configure_args '--with-target-subdir=$$1_subdir' '--exec-prefix=${prefix}/$$1_subdir'"
189    ;;
190  esac
191
192  # make sure that $1_subdir is not empty
193  test -n "$$1_subdir" || $1_subdir="."
194
195  ac_popdir=`pwd`
196  for ac_dir in $$1_configdirs; do
197
198    # Do not complain, so a configure script can configure whichever
199    # parts of a large source tree are present.
200    test -d $srcdir/$ac_dir || continue
201
202    AC_MSG_NOTICE([configuring in $$1_subdir/$ac_dir])
203    AS_MKDIR_P(["$$1_subdir/$ac_dir"])
204    _RTEMS_SRCPATHS(["$ac_dir"],["$$1_subdir"])
205
206    cd $$1_subdir/$ac_dir
207
208    # Check for guested configure; otherwise get Cygnus style configure.
209    if test -f $ac_srcdir/configure.gnu; then
210      ac_sub_configure="$SHELL '$ac_srcdir/configure.gnu'"
211    elif test -f $ac_srcdir/configure; then
212      ac_sub_configure="$SHELL '$ac_srcdir/configure'"
213    elif test -f $ac_srcdir/configure.in; then
214      ac_sub_configure=$ac_configure
215    else
216      AC_MSG_WARN([no configuration information is in $ac_dir])
217      ac_sub_configure=
218    fi
219
220    # The recursion is here.
221    if test -n "$ac_sub_configure"; then
222      # Make the cache file name correct relative to the subdirectory.
223      case $cache_file in
224      [[\\/]]* | ?:[[\\/]]* ) ac_sub_cache_file=$cache_file ;;
225      *) # Relative path.
226        ac_sub_cache_file=$ac_top_builddir$cache_file ;;
227      esac
228
229      ac_sub_configure_args="$ac_sub_configure_args '--cache-file=$ac_sub_cache_file'"
230      ac_sub_configure_args="$ac_sub_configure_args '--srcdir=$ac_srcdir'"
231
232      # The eval makes quoting arguments work.
233      ac_sub_configure_vars=
234      test -n "[$]CC_FOR_$2" && \
235        ac_sub_configure_vars="'CC=[$]CC_FOR_$2'"
236      test -n "[$]CXX_FOR_$2" && \
237        ac_sub_configure_vars="$ac_sub_configure_vars 'CXX=[$]CXX_FOR_$2'"
238      test -n "[$]CFLAGS_FOR_$2" && \
239        ac_sub_configure_vars="$ac_sub_configure_vars 'CFLAGS=[$]CFLAGS_FOR_$2'"
240      test -n "[$]CXXFLAGS_FOR_$2" && \
241        ac_sub_configure_vars="$ac_sub_configure_vars 'CXXFLAGS=[$]CXXFLAGS_FOR_$2'"
242
243      AC_MSG_NOTICE([running $ac_sub_configure $ac_sub_configure_args $ac_sub_configure_vars])
244      eval $ac_sub_configure $ac_sub_configure_args $ac_sub_configure_vars ||
245        AC_MSG_ERROR([$ac_sub_configure failed for $ac_dir])
246    fi
247
248    cd $ac_popdir
249  done
250 fi
251fi
252])
253])
254
255## PUBLIC: RTEMS_BUILD_CONFIG_SUBDIRS(build_subdir)
256# subdirs to be built for the build environment
257AC_DEFUN([RTEMS_BUILD_CONFIG_SUBDIRS],[
258m4_append([_RTEMS_BUILD_CONFIGDIRS_LIST],[ $1])
259dnl Always append to build_configdirs
260AC_SUBST(build_configdirs,"$build_configdirs $1")
261
262m4_divert_text([DEFAULTS],
263               [ac_subdirs_all="$ac_subdirs_all m4_normalize([$1])"])
264m4_expand_once([_RTEMS_COMMANDS_POST_CONFIG_SUBDIRS])
265])
266
267AC_DEFUN([_RTEMS_CONFIGURE_ARGS_PRUNE],
268[
269  for ac_arg in m4_if([$3],,[$ac_configure_args],[[$]$3]); do
270    if test -n "$ac_prev"; then
271      ac_prev=
272      continue
273    fi
274    # the eval casts away sh quotes
275    case `eval echo $ac_arg` in
276    -host* | --host* );;
277    -host ) ac_prev=host_alias;;
278    -target* | --target* );;
279    -target | --target ) ac_prev=target_alias;;
280    -build* | --build* );;
281    -build | --build ) ac_prev=build_alias;;
282    --cache* );;
283    *_alias=* );;
284    m4_if([$2],,,[$2])
285    *) $1="$$1 '$ac_arg'" ;;
286   esac
287  done
288])
289
290AC_DEFUN(_RTEMS_BUILD_CONFIG_PREPARE,[
291# Record the configure arguments in Makefile.
292m4_ifdef([_RTEMS_BUILD_CONFIGDIRS_LIST],
293[
294_RTEMS_CONFIGURE_ARGS_PRUNE([buildargs])
295buildargs="'--host=${build}' '--build=${build}' '--target=${target_alias}' ${buildargs}"
296AC_SUBST(buildargs)
297
298build_subdir="."
299],[])
300])
301
302## PUBLIC: RTEMS_HOST_CONFIG_SUBDIRS(host_subdir)
303# subdirs to be build for the host environment
304AC_DEFUN([RTEMS_HOST_CONFIG_SUBDIRS],[
305m4_append([_RTEMS_HOST_CONFIGDIRS_LIST],[ $1])dnl
306
307if test $build = $host;
308then
309  if test $host = $target;
310  then
311    _RTEMS_SUBST_IFNOT([build_configdirs],[$1])
312  else
313    _RTEMS_SUBST_IFNOT([build_configdirs],[$1])
314  fi
315else
316  if test $host = $target;
317  then
318    _RTEMS_SUBST_IFNOT([host_configdirs],[$1])
319  else
320    if test $build = $target;
321    then
322      _RTEMS_SUBST_IFNOT([host_configdirs],[$1])
323    else
324      _RTEMS_SUBST_IFNOT([host_configdirs],[$1])
325    fi
326  fi
327fi
328
329m4_divert_text([DEFAULTS],
330               [ac_subdirs_all="$ac_subdirs_all m4_normalize([$1])"])
331m4_expand_once([_RTEMS_COMMANDS_POST_CONFIG_SUBDIRS])
332])
333
334AC_DEFUN(_RTEMS_HOST_CONFIG_PREPARE,[
335m4_ifdef([_RTEMS_HOST_CONFIGDIRS_LIST],
336[
337# Record configure arguments in Makefile.
338_RTEMS_CONFIGURE_ARGS_PRUNE([hostargs])
339hostargs="'--host=${host_alias}' '--build=${build}' '--target=${target_alias}' ${hostargs}"
340AC_SUBST(hostargs)
341
342host_subdir="${host_alias}"
343],[])
344])
345
346## PUBLIC: RTEMS_TARGET_CONFIG_SUBDIRS(target_subdir)
347# subdirs to be build for the target environment
348AC_DEFUN([RTEMS_TARGET_CONFIG_SUBDIRS],[
349m4_append([_RTEMS_TARGET_CONFIGDIRS_LIST],[ $1])
350
351if test $build = $host;
352then
353  if test $host = $target;
354  then
355    _RTEMS_SUBST_IFNOT([build_configdirs],[$1])
356  else
357    _RTEMS_SUBST_IFNOT([target_configdirs],[$1])
358  fi
359else
360  if test $host = $target;
361  then
362    _RTEMS_SUBST_IFNOT([host_configdirs],[$1])
363  else
364    if test $build = $target;
365    then
366      _RTEMS_SUBST_IFNOT([build_configdirs],[$1])
367    else
368      _RTEMS_SUBST_IFNOT([target_configdirs],[$1])
369    fi
370  fi
371fi
372
373m4_divert_text([DEFAULTS],
374               [ac_subdirs_all="$ac_subdirs_all m4_normalize([$1])"])
375m4_expand_once([_RTEMS_COMMANDS_POST_CONFIG_SUBDIRS])
376])
377
378AC_DEFUN(_RTEMS_TARGET_CONFIG_PREPARE,[
379m4_ifdef([_RTEMS_TARGET_CONFIGDIRS_LIST],
380[
381# Record the configure arguments in Makefile.
382_RTEMS_CONFIGURE_ARGS_PRUNE([targetargs])
383targetargs="'--host=${target_alias}' '--build=${build}' '--target=${target_alias}' ${targetargs}"
384AC_SUBST(targetargs)
385
386target_subdir="${target_alias}"
387],[])
388])
Note: See TracBrowser for help on using the repository browser.