source: rtems/acinclude.m4 @ 9cf7774

4.104.114.84.9
Last change on this file since 9cf7774 was 9cf7774, checked in by Ralf Corsepius <ralf.corsepius@…>, on Nov 5, 2002 at 6:34:36 PM

2002-11-05 Ralf Corsepius <corsepiu@…>

  • acinclude.m4: Adapations to autoconf > 2.52.
  • Property mode set to 100644
File size: 10.8 KB
Line 
1## All directories belong in one of 3 categories.
2## ${HOST_CONFIGDIRS_LIST} is directories we build using the host tools.
3## ${TARGET_CONFIGDIRS_LIST} is directories we build using the target tools.
4## ${BUILD_CONFIGDIRS_LIST} is directories we build using the build tools
5
6
7dnl RTEMS_ARG_VAR(VAR,HELP-STRING)
8dnl An internal macros to have help strings pretty
9dnl printed with configure --help, without letting autoconf spoil config subdir
10dnl environments by trying to propagate them
11dnl Stripped down version of autoconf-2.52's AC_ARG_VAR.
12
13AC_DEFUN([_RTEMS_ARG_VAR],
14[
15m4_expand_once([m4_divert_once([HELP_VAR],
16[AC_HELP_STRING([$1], [$2], [              ])])],
17      [$0($1)])dnl
18])
19
20AC_DEFUN([_RTEMS_SUBST_IFNOT],
21[AS_IF([`echo " [$]$1 " | grep " $2 " > /dev/null`],
22  [],
23  [AC_SUBST([$1],["[$]$1 $2"])])
24])
25
26AC_DEFUN([_RTEMS_COMMANDS_POST_CONFIG_SUBDIRS],
27[
28AC_CONFIG_COMMANDS_PRE([
29_RTEMS_BUILD_CONFIG_PREPARE
30_RTEMS_HOST_CONFIG_PREPARE
31_RTEMS_TARGET_CONFIG_PREPARE
32
33AS_IF([test $build = $host],
34[
35  AS_IF([test $host = $target],
36  [dnl b=h, h=t, t=b
37    BUILD_SUBDIRS="${build_configdirs}"
38    build_configdirs="${build_configdirs}"
39    HOST_SUBDIRS=""
40    host_configdirs=""
41    TARGET_SUBDIRS=""
42    target_configdirs=""],
43  [dnl b=h, h!=t, t!=b
44    BUILD_SUBDIRS="${build_configdirs}"
45    build_configdirs="${build_configdirs}"
46    HOST_SUBDIRS=""
47    host_configdirs=""
48    TARGET_SUBDIRS=`echo "${target_configdirs}" | \
49      sed -e "s%\([[^ ]][[^ ]]*\)%$target_alias/\1%g"`
50    target_configdirs="${target_configdirs}"
51  ])
52],[
53  AS_IF([test $host = $target],
54  [ dnl b!=h, h=t, b!=t
55    BUILD_SUBDIRS="${build_configdirs}"
56    build_configdirs="${build_configdirs}"
57    HOST_SUBDIRS=`echo "${host_configdirs}" | \
58      sed -e "s%\([[^ ]][[^ ]]*\)%$host_alias/\1%g"`
59    host_configdirs="${host_configdirs}"
60    TARGET_SUBDIRS=""
61    target_configdirs=""],
62  [
63    AS_IF([test $build = $target],
64    [dnl b!=h, h!=t, b=t
65      BUILD_SUBDIRS="${build_configdirs}"
66      build_configdirs="${build_configdirs}"
67      HOST_SUBDIRS=`echo "${host_configdirs}" | \
68        sed -e "s%\([[^ ]][[^ ]]*\)%$host_alias/\1%g"`
69      host_configdirs="${host_configdirs}"
70      TARGET_SUBDIRS=""
71      target_configdirs=""],
72    [dnl b!=h, h!=t, b!=t
73      BUILD_SUBDIRS="${build_configdirs}"
74      build_configdirs="${build_configdirs}"
75      HOST_SUBDIRS=`echo "${host_configdirs}" | \
76        sed -e "s%\([[^ ]][[^ ]]*\)%$host_alias/\1%g"`
77      host_configdirs="${host_configdirs}"
78      TARGET_SUBDIRS=`echo "${target_configdirs}" | \
79        sed -e "s%\([[^ ]][[^ ]]*\)%$target_alias/\1%g"`
80      target_configdirs="${target_configdirs}"
81    ])
82  ])
83])
84
85AC_SUBST(HOST_SUBDIRS)
86AC_SUBST(TARGET_SUBDIRS)
87AC_SUBST(BUILD_SUBDIRS)
88])
89
90  AC_CONFIG_COMMANDS_POST([
91    _RTEMS_OUTPUT_SUBDIRS([build],[BUILD])
92    _RTEMS_OUTPUT_SUBDIRS([host],[HOST])
93    _RTEMS_OUTPUT_SUBDIRS([target],[TARGET])
94  ])
95])
96
97dnl _RTEMS_SRCPATHS(BUILD-DIR-NAME)
98dnl ----------------------------
99dnl Inputs:
100dnl   - BUILD-DIR-NAME is `top-build -> build' and `top-src -> src'
101dnl   - `$srcdir' is `top-build -> top-src'
102dnl
103dnl Outputs:
104dnl - `ac_builddir' is `.', for symmetry only.
105dnl - `ac_top_builddir' is `build -> top_build'.
106dnl      If not empty, has a trailing slash.
107dnl - `ac_srcdir' is `build -> src'.
108dnl - `ac_top_srcdir' is `build -> top-src'.
109dnl
110dnl and `ac_buildpath' etc., the absolute paths.
111m4_define([_RTEMS_SRCPATHS],
112[
113m4_if([$2],,
114[dstdir=$1],
115[case "$2" in
116"." | "" )      # No subdir was given
117  dstdir=$1;;
118* )             # A subdir was given
119  dstdir=$2/$1;;
120esac])
121ac_builddir=.
122
123AS_IF([test $dstdir != .],
124[ # Strip off leading ./
125  ac_builddir_suffix=/`echo $dstdir | sed 's,^\.[[\\/]],,'`
126  ac_srcdir_suffix=/`echo $1 | sed 's,^\.[[\\/]],,'`
127  # A "../" for each directory in $ac_dir_suffix.
128  ac_top_builddir=`echo "$ac_builddir_suffix" | sed 's,/[[^\\/]]*,../,g'`
129],[
130  ac_dir_suffix= ac_top_builddir=
131])
132
133case $srcdir in
134  .)  # No --srcdir option.  We are building in place.
135    ac_srcdir=.
136    if test -z "$ac_top_builddir"; then
137       ac_top_srcdir=.
138    else
139       ac_top_srcdir=`echo $ac_top_builddir | sed 's,/$,,'`
140    fi ;;
141  [[\\/]]* | ?:[[\\/]]* )  # Absolute path.
142    ac_srcdir=$srcdir$ac_srcdir_suffix;
143    ac_top_srcdir=$srcdir;
144    ;;
145  *) # Relative path.
146    ac_srcdir=$ac_top_builddir$srcdir$ac_srcdir_suffix;
147    ac_top_srcdir=$ac_top_builddir$srcdir;
148    ;;
149esac
150dnl Don't blindly perform a `cd $1/$ac_foo && pwd` since $ac_foo can be
151dnl absolute.
152
153ac_buildpath=`cd $dstdir && cd $ac_builddir && pwd`
154ac_top_buildpath=`cd $dstdir && cd $ac_top_builddir && pwd`
155ac_srcpath=`cd $dstdir && cd $ac_srcdir && pwd`
156ac_top_srcpath=`cd $dstdir && cd $ac_top_srcdir && pwd`
157])# _AC_SRCPATHS
158
159dnl _RTEMS_OUTPUT_SUBDIRS([host|target|build],[HOST|TARGET|BUILD])
160AC_DEFUN([_RTEMS_OUTPUT_SUBDIRS],[
161m4_ifdef([_RTEMS_$2_CONFIGDIRS_LIST],
162[
163_RTEMS_ARG_VAR([CC_FOR_$2],
164  [c-compiler to be used for $1 subdirs (default: auto-detected)])
165_RTEMS_ARG_VAR([CFLAGS_FOR_$2],
166  [c-flags to be used for $1 subdirs (default: provided by autoconf)])
167if test "$no_recursion" != yes; then
168
169 if test -n "${$2_SUBDIRS}"; then
170   RTEMS_CONFIGURE_ARGS_QUOTE([ac_sub_configure_args],[
171     -prefix | --prefix | --prefi | --pref | --pre | --pr | --p)
172       ac_prev=prefix ;;
173     -prefix=* | --prefix=* | --prefi=* | --pref=* | --pre=* | --pr=* | --p=*)
174       ;;
175   ],[$1args])
176
177  # Always prepend --prefix to ensure using the same prefix
178  # in subdir configurations.
179  ac_sub_configure_args="'--prefix=$prefix' $ac_sub_configure_args"
180
181  case "$$1_subdir" in
182  "." ) ;;
183  * )
184    ac_sub_configure_args="$ac_sub_configure_args '--with-target-subdir=$$1_subdir' '--exec-prefix=${prefix}/$$1_subdir'"
185    ;;
186  esac
187
188  # make sure that $1_subdir is not empty
189  test -n "$$1_subdir" || $1_subdir="."
190
191  ac_popdir=`pwd`
192  for ac_dir in $$1_configdirs; do
193
194    # Do not complain, so a configure script can configure whichever
195    # parts of a large source tree are present.
196    test -d $srcdir/$ac_dir || continue
197
198    AC_MSG_NOTICE([configuring in $$1_subdir/$ac_dir])
199    AS_MKDIR_P(["$$1_subdir/$ac_dir"])
200    _RTEMS_SRCPATHS(["$ac_dir"],["$$1_subdir"])
201
202    cd $$1_subdir/$ac_dir
203
204    # Check for guested configure; otherwise get Cygnus style configure.
205    if test -f $ac_srcdir/configure.gnu; then
206      ac_sub_configure="$SHELL '$ac_srcdir/configure.gnu'"
207    elif test -f $ac_srcdir/configure; then
208      ac_sub_configure="$SHELL '$ac_srcdir/configure'"
209    elif test -f $ac_srcdir/configure.in; then
210      ac_sub_configure=$ac_configure
211    else
212      AC_MSG_WARN([no configuration information is in $ac_dir])
213      ac_sub_configure=
214    fi
215
216    # The recursion is here.
217    if test -n "$ac_sub_configure"; then
218      # Make the cache file name correct relative to the subdirectory.
219      case $cache_file in
220      [[\\/]]* | ?:[[\\/]]* ) ac_sub_cache_file=$cache_file ;;
221      *) # Relative path.
222        ac_sub_cache_file=$ac_top_builddir$cache_file ;;
223      esac
224
225      AC_MSG_NOTICE([running $ac_sub_configure $ac_sub_configure_args \
226           --cache-file=$ac_sub_cache_file --srcdir=$ac_srcdir])
227      # The eval makes quoting arguments work.
228      ac_sub_configure_vars=
229      test -n "[$]CC_FOR_$2" && \
230        ac_sub_configure_vars="'CC=[$]CC_FOR_$2'"
231      test -n "[$]CFLAGS_FOR_$2" && \
232        ac_sub_configure_vars="$ac_sub_configure_vars 'CFLAGS=[$]CFLAGS_FOR_$2'"
233      eval $ac_sub_configure_vars \
234        $ac_sub_configure $ac_sub_configure_args \
235          --cache-file=$ac_sub_cache_file --srcdir=$ac_srcdir ||
236        AC_MSG_ERROR([$ac_sub_configure failed for $ac_dir])
237    fi
238
239    cd $ac_popdir
240  done
241 fi
242fi
243])
244])
245
246## PUBLIC: RTEMS_BUILD_CONFIG_SUBDIRS(build_subdir)
247# subdirs to be built for the build environment
248AC_DEFUN([RTEMS_BUILD_CONFIG_SUBDIRS],[
249m4_append([_RTEMS_BUILD_CONFIGDIRS_LIST],[ $1])
250dnl Always append to build_configdirs
251AC_SUBST(build_configdirs,"$build_configdirs $1")
252
253m4_divert_text([DEFAULTS],
254               [ac_subdirs_all="$ac_subdirs_all m4_normalize([$1])"])
255m4_expand_once([_RTEMS_COMMANDS_POST_CONFIG_SUBDIRS])
256])
257
258AC_DEFUN([_RTEMS_CONFIGURE_ARGS_PRUNE],
259[
260  for ac_arg in m4_if([$3],,[$ac_configure_args],[[$]$3]); do
261    if test -n "$ac_prev"; then
262      ac_prev=
263      configure
264    fi
265    # the eval casts away sh quotes
266    case `eval echo $ac_arg` in
267    -host* | --host* );;
268    -host ) ac_prev=host_alias;;
269    -target* | --target* );;
270    -target | --target ) ac_prev=target_alias;;
271    -build* | --build* );;
272    -build | --build ) ac_prev=build_alias;;
273    --cache* );;
274    *_alias=* );;
275    m4_if([$2],,,[$2])
276    *) $1="$$1 '$ac_arg'" ;;
277   esac
278  done
279])
280
281AC_DEFUN(_RTEMS_BUILD_CONFIG_PREPARE,[
282# Record the configure arguments in Makefile.
283m4_ifdef([_RTEMS_BUILD_CONFIGDIRS_LIST],
284[
285_RTEMS_CONFIGURE_ARGS_PRUNE([buildargs])
286buildargs="'--host=${build}' '--build=${build}' '--target=${target_alias}' ${buildargs}"
287AC_SUBST(buildargs)
288
289build_subdir="."
290],[])
291])
292
293## PUBLIC: RTEMS_HOST_CONFIG_SUBDIRS(host_subdir)
294# subdirs to be build for the host environment
295AC_DEFUN([RTEMS_HOST_CONFIG_SUBDIRS],[
296m4_append([_RTEMS_HOST_CONFIGDIRS_LIST],[ $1])dnl
297
298if test $build = $host;
299then
300  if test $host = $target;
301  then
302    _RTEMS_SUBST_IFNOT([build_configdirs],[$1])
303  else
304    _RTEMS_SUBST_IFNOT([build_configdirs],[$1])
305  fi
306else
307  if test $host = $target;
308  then
309    _RTEMS_SUBST_IFNOT([host_configdirs],[$1])
310  else
311    if test $build = $target;
312    then
313      _RTEMS_SUBST_IFNOT([host_configdirs],[$1])
314    else
315      _RTEMS_SUBST_IFNOT([host_configdirs],[$1])
316    fi
317  fi
318fi
319
320m4_divert_text([DEFAULTS],
321               [ac_subdirs_all="$ac_subdirs_all m4_normalize([$1])"])
322m4_expand_once([_RTEMS_COMMANDS_POST_CONFIG_SUBDIRS])
323])
324
325AC_DEFUN(_RTEMS_HOST_CONFIG_PREPARE,[
326m4_ifdef([_RTEMS_HOST_CONFIGDIRS_LIST],
327[
328# Record configure arguments in Makefile.
329_RTEMS_CONFIGURE_ARGS_PRUNE([hostargs])
330hostargs="'--host=${host_alias}' '--build=${build}' '--target=${target_alias}' ${hostargs}"
331AC_SUBST(hostargs)
332
333host_subdir="${host_alias}"
334],[])
335])
336
337## PUBLIC: RTEMS_TARGET_CONFIG_SUBDIRS(target_subdir)
338# subdirs to be build for the target environment
339AC_DEFUN([RTEMS_TARGET_CONFIG_SUBDIRS],[
340m4_append([_RTEMS_TARGET_CONFIGDIRS_LIST],[ $1])
341
342if test $build = $host;
343then
344  if test $host = $target;
345  then
346    _RTEMS_SUBST_IFNOT([build_configdirs],[$1])
347  else
348    _RTEMS_SUBST_IFNOT([target_configdirs],[$1])
349  fi
350else
351  if test $host = $target;
352  then
353    _RTEMS_SUBST_IFNOT([host_configdirs],[$1])
354  else
355    if test $build = $target;
356    then
357      _RTEMS_SUBST_IFNOT([build_configdirs],[$1])
358    else
359      _RTEMS_SUBST_IFNOT([target_configdirs],[$1])
360    fi
361  fi
362fi
363
364m4_divert_text([DEFAULTS],
365               [ac_subdirs_all="$ac_subdirs_all m4_normalize([$1])"])
366m4_expand_once([_RTEMS_COMMANDS_POST_CONFIG_SUBDIRS])
367])
368
369AC_DEFUN(_RTEMS_TARGET_CONFIG_PREPARE,[
370m4_ifdef([_RTEMS_TARGET_CONFIGDIRS_LIST],
371[
372# Record the configure arguments in Makefile.
373_RTEMS_CONFIGURE_ARGS_PRUNE([targetargs])
374targetargs="'--host=${target_alias}' '--build=${build}' '--target=${target_alias}' ${targetargs}"
375AC_SUBST(targetargs)
376
377target_subdir="${target_alias}"
378],[])
379])
Note: See TracBrowser for help on using the repository browser.